C
C
C     LIST OF SUBROUTINES IN THIS FILE 
C
C     HC_CPLEQN : LIQUID HEAT CAPACITY EQUATIONS 
C	HC_CPLCSP : LIQUID HEAT CAPACITY ESITIMATION USING A 
C				CORRESPONDING STATE METHOD PROPOSED BY BONDI
C
C
C*******************************************************************
C
C KDB THEMOPHYSICAL PROPERTIES CALCULATION FORTRAN ROUTINE LIBRARY 
C
C [NAME   ]  HC_CPLEQN 
C
C [TYPE   ]  FORTRAN SUBROUTINE                              
C
C [PURPOSE]  LIQUID HEAT CAPACITY USING INTERNAL CORRELATION EQUATION 
C
C [USAGE  ]  CALL HC_CPLEQN(ICN,T,CPL,IST)
C
C [ARGUMENTS]                                                                  
C     ICN        : COMPONENT NUMBER (1-50) TO CALCULATE LIQUID HEAT CAPACITY
C													(INTEGER, INPUT) 
C     T          : TEMPERATURE IN KELVIN (REAL*8, INPUT) 
C
C     CPL        : LIQUID HAT CAPACITY IN KJ/KG-MOL.K (REAL*8, OUTPUT) 
C     IST        : STATUS OF CALCULATION (INTEGER, OUTPUT) 
C                = 0	    : NORMAL TERMINATION 
C                = 401   	: LIQUID HEAT CAPACITY COEFFICIENT NOT AVAILABLE 
C                = 402    : OUT OF RANGE FOR THE APPLICATION  
C
C [COMMENTS]
C     
C [REQUIRED COMMON BLOCKS]
C     COMMON /HC_KCPL/ LIQUID HEAT CAPACITY COEFFICIENTS 
C                                                                   
C [REQUIRED SUBROUTINES OR FUNCTIONS] 
C	NONE 
C
C [REFERENCE]
C     NONE  
C	
C [REVISION INFORMATION]
C     1.PROGRMAMMED BY J.W.KANG, KOREA UNIVERSITY, 1996
C     2.REVISED BY J.W.KANG, KOREA UNIVERSITY, 2000                                                              
C     3.REVISED BY J.W.KANG, KOREA UNIVERSITY, 2001  
C*******************************************************************
      SUBROUTINE HC_CPLEQN(ICN,T,CPL,IST)
      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
	INTEGER IST,ICN  
      REAL*8  T,CPL
      COMMON/HC_KCPL/IEQ_CPL(50),CPL_A(50),CPL_B(50),CPL_C(50),
     1	CPL_D(50),CPL_E(50),CPL_F(50),CPL_G(50),CPL_T1(50),CPL_T2(50)
C --- INITIALIZATION 
      IST = 0
	CPL = 0.0
C --- CHECK IF EQUATION COEFF.S AVAILABLE 
	IF(IEQ_CPL(ICN).LE.0) IST = 401 
C --- CHECK IF THE RANGE OF APPLICATION 
	IF((T.LT.CPL_T1(ICN)).OR.(T.GT.CPL_T2(ICN)) ) IST = 402 
	IF(IST.NE.0) RETURN 
C --- LIQUID HEAT CAPAICITY CALCULATION 
      CPL = CPL_A(ICN)+CPL_B(ICN)*T+CPL_C(ICN)*T*T+CPL_D(ICN)*T*T*T 
      RETURN
      END
C*******************************************************************
C
C KDB THEMOPHYSICAL PROPERTIES CALCULATION FORTRAN ROUTINE LIBRARY 
C
C [NAME   ]  HC_CPLCSP
C
C [TYPE   ]  FORTRAN SUBROUTINE                              
C
C [PURPOSE]  HEAT CAPACITY ESTIMATION USING USING A 
C            CORRESPONDING STATE METHOD PROPOSED BY BONDI
C
C [USAGE  ]  CALL HC_CPLCSP(ICN,T,CPL,IST)
C
C [ARGUMENTS]                                                                  
C     ICN       : COMPONENT NUMBER (1-50) TO CALCULATE LIQUID HEAT CAPACITY
C													(INTEGER, INPUT) 
C     T          : TEMPERATURE IN KELVIN (REAL*8, INPUT) 
C
C     CPL	       : LIQUID HEAT CAPACITY IN KJ/KG-MOL.K (REAL*8, OUTPUT) 
C     IST        : STATUS OF CALCULATION (INTEGER, OUTPUT) 
C                = 0	    : NORMAL TERMINATION 
C                = 411   	: IDEAL GAS HEAT CAPACITY DATA NOT AVAILABLE 
C                = 412    : CRITICAL TEMPERATURE DATA NOT AVAILABLE 
C                = 413    : ACCENTRIC FACTOR DATA NOT AVAILABLE 
C
C [COMMENTS]
C     
C [REQUIRED COMMON BLOCKS]
C     COMMON /HC_PROP/ COMPONENT BASIC PROPERTIES 
C     COMMON /HC_KCPG/ IDEAL GAS HEAT CAPACITY COEFFICIENTS 
C                                                                   
C [REQUIRED SUBROUTINES OR FUNCTIONS] 
C	NONE 
C
C [REFERENCE]
C     1. Poling et al., Properies of Gases and Liquids,
C					 5th ed. McGraw-Hill, New York
C	
C [REVISION INFORMATION]
C     1.PROGRMAMMED BY J.W.KANG, KOREA UNIVERSITY, 1996
C     2.REVISED BY J.W.KANG, KOREA UNIVERSITY, 2000                                                              
C     3.REVISED BY J.W.KANG, KOREA UNIVERSITY, 2001  
C*******************************************************************
      SUBROUTINE HC_CPLCSP(ICN,T,CPL,IST)
      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
	INTEGER IST,ICN  
      REAL*8  T,CPL,DCP,TR,CPG0
      COMMON/HC_PROP/WT(50),TB(50),TF(50),TC(50),PC(50),VC(50),ZC(50)
	1	,ACCF(50),WSRK(50),VEST(50),ZRA(50),SOLP(50),VOLP(50)
     2	,QI(50),RI(50),DM(50) 
      COMMON/HC_KCPG/IEQ_CPG(50),CPG_A(50),CPG_B(50),CPG_C(50),
     1	CPG_D(50),CPG_E(50),CPG_F(50),CPG_G(50),CPG_T1(50),CPG_T2(50)
C --- INITIALIZATION 
      IST = 0
	CPL = 0.0
C --- CHECK IF ALL THE AVAILABALE DATA EXISTS 
	IF(IEQ_CPG(ICN).EQ.0) IST = 411 
	IF(TC(ICN).LE.0.) IST = 412
	IF(ACCF(ICN).LE.0.) IST = 413
	IF(IST.NE.0) RETURN 
C --- HEAT OF VAPORIZATION AT BOILIN POINT USING VETERE METHOD 
	TR = T/TC(ICN) 
	CALL HC_CPGEQN(ICN,T,CPG0,IST) 
	DCP = 1.586 + 0.49 /(1.D0-TR) + ACCF(ICN)*(4.2775 + 
	1	6.3*(1.D0-TR)**(1.D0/3.D0) / TR + 0.4355 / (1.D0-TR) ) 
	CPL = 8.314*DCP + CPG0 
      RETURN
      END
C*******************************************************************
C     END OF FILE