C
C
C     LIST OF SUBROUTINES IN THIS FILE 
C
C     HC_THGEQN : GAS THERMAL CONDUCTIVITY EQUATIONS 
C     HC_THGCHUNG : GAS THERMAL CONDUCTIVITY ESTIMATION
C					BY CHUNG ET AL. METHOD
C	HC_THGCHUNG_HP : GAS THERMAL CONDUCTIVITY ESTIMATION
C					BY CHUNG ET AL. METHOD FOR HIGH PRESSURE
C
C
C*******************************************************************
C
C KDB THEMOPHYSICAL PROPERTIES CALCULATION FORTRAN ROUTINE LIBRARY 
C
C [NAME   ]  HC_THGEQN 
C
C [TYPE   ]  FORTRAN SUBROUTINE                              
C
C [PURPOSE]  GAS THERMAL CONDUCTIVITY CALCULATION USING INTERNAL CORRELATION EQUATION 
C
C [USAGE  ]  CALL HC_THGEQN(ICN,T,THL,IST)
C
C [ARGUMENTS]                                                                  
C     ICN		: COMPONENT NUMBER (1-50) TO CALCULATE GAS THERMAL CONDUCTIVITY
C	                                           (INTEGER, INPUT) 
C     T		: TEMPERATURE IN KELVIN (REAL*8, INPUT) 
C
C     THG	    : GAS THERMAL CONDUCTIVITY IN W/m.K (REAL*8, OUTPUT) 
C     IST        : STATUS OF CALCULATION (INTEGER, OUTPUT) 
C                = 0	    : NORMAL TERMINATION 
C                = 701   	: GAS THERMAL CONDUCTIVITY COEFFICIENT NOT AVAILABLE 
C                = 702    : OUT OF RANGE FOR THE APPLICATION  
C
C [COMMENTS]
C     
C [REQUIRED COMMON BLOCKS]
C     COMMON /HC_KTHG/ GAS THERMAL CONDUCTIVITY COEFFICIENTS 
C                                                                   
C [REQUIRED SUBROUTINES OR FUNCTIONS] 
C	NONE 
C
C [REFERENCE]
C     NONE  
C	
C [REVISION INFORMATION]
C     1.PROGRAMED BY J.W.KANG, KOREA UNIVERSITY, 2001  
C     2.REVISED BY Y.S.KIM, KOREA UNIVERSITY, 2002 
C*******************************************************************

      SUBROUTINE HC_THGEQN(ICN,T,THG,IST)
      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
	INTEGER IST,ICN  
      REAL*8  T,THG
      COMMON/HC_KTHG/IEQ_THG(50),THG_A(50),THG_B(50),THG_C(50),
     1	THG_D(50),THG_E(50),THG_F(50),THG_G(50),THG_T1(50),THG_T2(50)

C --- INITIALIZATION 
      IST = 0
	THG = 0.D0
C --- CHECK IF EQUATION COEFF.S AVAILABLE 
	IF(IEQ_THG(ICN).LE.0) IST = 701 
C --- CHECK IF THE RANGE OF APPLICATION 
	IF(IST.NE.0) RETURN 
C --- LIQUID HEAT CAPAICITY CALCULATION 
	THG =THG_A(ICN)+THG_B(ICN)*T+THG_C(ICN)*T*T+THG_D(ICN)*T*T*T
	
      RETURN
      END

C*******************************************************************
C
C KDB THEMOPHYSICAL PROPERTIES CALCULATION FORTRAN ROUTINE LIBRARY 
C
C [NAME   ]  HC_THGCHUNG
C
C [TYPE   ]  FORTRAN SUBROUTINE                              
C
C [PURPOSE]  GAS THERMAL CONDUCTIVITY ESTIMATION BY CHUNG ET AL. METHOD
C			FOR LOW PRESSURE GAS
C
C [USAGE  ]  CALL HC_THGCHUNG(ICN,T,THG,IST)
C
C [ARGUMENTS]                                                                  
C     ICN       : COMPONENT NUMBER (1-50) TO CALCULATE GAS THERMAL CONDUCTIVITY
C															(INTEGER, INPUT) 
C     T          : TEMPERATURE IN KELVIN (REAL*8, INPUT) 
C
C     THG	       : THERMAL CONDUCTIVITY IN Watt/(m.K) (REAL*8, OUTPUT) 
C     IST        : STATUS OF CALCULATION (INTEGER, OUTPUT) 
C                = 0	    : NORMAL TERMINATION 
C                = 711   	: CRITICAL TEMPERATURE DATA NOT AVAILABLE 
C                = 712    : ACCENTRIC FACTOR DATA NOT AVAILABLE
C			   = 713	: MOLECULAR WEIGHT DATA NOT AVAILABLE
C                = 714    : NOT OBTAINED LOW PRESSURE GAS VISCOSITY 
C                = 715    : NOT OBTAINED GAS HEAT CAPACITY
C			   	
C
C [COMMENTS]
C     
C [REQUIRED COMMON BLOCKS]
C     COMMON /HC_PROP/ COMPONENT BASIC PROPERTIES
C                                                                   
C [REQUIRED SUBROUTINES OR FUNCTIONS] 
C	SUBROUTINE HC_VSGEQN
C	SUBROUTINE HC_VSGCHUNG_LP
C	SUBROUTINE HC_CPGEQN 
C
C [REFERENCE]
C     1. CHUNG ET AL.,IND.ENG.CHEM.FUNDAM.,23, p8 (1984)
C     2. CHUNG ET AL.,IND.END.CHEM.RES.,27, p671(1988)
C	
C [REVISION INFORMATION]
C     1.PROGRMAMMED BY Y.S.KIM, KOREA UNIVERSITY, 2002
C*******************************************************************
      SUBROUTINE HC_THGCHUNG(ICN,T,THG,IST)
      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
	INTEGER IST,ICN  
      REAL*8  T,THG
      COMMON/HC_PROP/WT(50),TB(50),TF(50),TC(50),PC(50),VC(50),ZC(50)
	1	,ACCF(50),WSRK(50),VEST(50),ZRA(50),SOLP(50),VOLP(50)
     2	,QI(50),RI(50),DM(50) 
	DATA RR / 8.314D0 / 
C --- INITIALIZATION 
      IST = 0
	THG = 0.0
	I = ICN
C --- CHECK IF ALL THE AVAILABALE DATA EXISTS 
	IF(TC(ICN).LE.0.) IST = 711
	IF(ACCF(ICN).LE.0.) IST = 712
	IF(WT(ICN).LE.0.) IST = 713

	IF(IST.NE.0) RETURN 
C --- LOW PRESSURE GAS VISCOSITY CALCULATION
	CALL HC_VSGEQN(I,T,VSG,ISTVSG)
	VSG = VSG*1.D-3			! cP -->N.s/m^2
	IF(ISTVSG.NE.0) THEN
		CALL HC_VSGCHUNG_LP(I,T,VSG,ISTVSG)
		VSG = VSG*1.D-7		! MICRO POISE -->N.s/m^2
	ENDIF
	IF(ISTVSG.NE.0) THEN
		IST = 714
		RETURN
	ENDIF
C --- HEAT CAPACITY CALCULATION
	CALL HC_CPGEQN(I,T,CPG,ISTCPG)  
	IF (ISTCPG.NE.0) THEN
		IST = 715
		RETURN
	ENDIF
	CV = CPG - RR

C --- THERMAL CONDUCTIVITY CALCUALTION

	TR = T / TC(I)
	ZZ = 2.D0+10.5D0*TR*TR
	ALPHA = CV/RR-1.5D0
	BETA = .7862D0-(.7109D0-1.3168D0*ACCF(I))*ACCF(I)
	TERM1 = .215D0+.28288D0*ALPHA-1.061D0*BETA+.26665*ZZ
	TERM2 = .6366D0+BETA*ZZ+1.061D0*ALPHA*BETA
	PSI = 1.D0+ALPHA*TERM1/TERM2
	THG = 3.75D0*PSI*RR*VSG/WT(I)/1.D-3 
	 
      RETURN
      END

C*******************************************************************
C
C KDB THEMOPHYSICAL PROPERTIES CALCULATION FORTRAN ROUTINE LIBRARY 
C
C [NAME   ]  HC_THGCHUNG_HP
C
C [TYPE   ]  FORTRAN SUBROUTINE                              
C
C [PURPOSE]  GAS THERMAL CONDUCTIVITY ESTIMATION BY CHUNG ET AL. METHOD
C			FOR HIGH PRESSURE GAS
C
C [USAGE  ]  CALL HC_THGCHUNG_HP(ICN,T,P,THG,IST)
C
C [ARGUMENTS]                                                                  
C     ICN       : COMPONENT NUMBER (1-50) TO CALCULATE GAS THERMAL CONDUCTIVITY
C															(INTEGER, INPUT) 
C     T          : TEMPERATURE IN KELVIN (REAL*8, INPUT) 
C	P		   : PRESSURE IN BAR (REAL*8, INPUT)
C	RHO		   : EXPERIMENTAL DENSITY (REAL*8, INPUT) 
C	IEXP	   : CALCULATION OPTION FOR DENSITY
C			   = 0		: IF NOT DENSITY DATA
C			   = NOT ZERO : IF THERE IS DENSITY DATA
C	 
C     THG	       : THERMAL CONDUCTIVITY IN Watt/(m.K) (REAL*8, OUTPUT) 
C     IST        : STATUS OF CALCULATION (INTEGER, OUTPUT) 
C                = 0	    : NORMAL TERMINATION 
C                = 721   	: CRITICAL TEMPERATURE DATA NOT AVAILABLE 
C                = 722   	: CRITICAL VOLUME DATA NOT AVAILABLE 
C                = 723    : ACCENTRIC FACTOR DATA NOT AVAILABLE
C			   = 724	: DIPOLE MOMENT DATA NOT AVAILABLE
C			   = 725	: MOLECULAR WEIGHT DATA NOT AVAILABLE
C                = 726    : NOT OBTAINED LOW PRESSURE GAS VISCOSITY 
C                = 727    : NOT OBTAINED GAS HEAT CAPACITY
C			   = 1728   : NO CONVERGENCE IN CALCULATION OF DENSITY
C									BY EQUATION OF STATE(SRK)
C
C [COMMENTS]
C     IF YOU DON'T HAVE A DENSITY DATA, YOU GIVE PRESSURE AS A INPUT.
C	OTHERWISE, YOU DON'T NEED PRESSURE, BUT MUST GIVE A DENSTIY DATA AS A INPUT. 
C
C [REQUIRED COMMON BLOCKS]
C     COMMON /HC_PROP/ COMPONENT BASIC PROPERTIES 
C                                                                   
C [REQUIRED SUBROUTINES OR FUNCTIONS] 
C	SUBROUTINE CB_SRK
C	SUBROUTINE CHUNGKP 
C	SUBROUTINE CPGEQN
C	SUBROUTINE VSGEQN
C	SUBROUTINE VSGCHUNG_LP
C
C [REFERENCE]
C     1. CHUNG ET AL.,IND.ENG.CHEM.FUNDAM.,23, p8 (1984)
C     2. CHUNG ET AL.,IND.END.CHEM.RES.,27, p671(1988)
C	
C [REVISION INFORMATION]
C     1.PROGRMAMMED BY Y.S.KIM, KOREA UNIVERSITY, 2002
C*******************************************************************
      SUBROUTINE HC_THGCHUNG_HP(ICN,T,P,THG,RHO,IEXP,IST)
      IMPLICIT DOUBLE PRECISION (A-H,O-Z)
	INTEGER IST,ICN  
      REAL*8  T,THG
      COMMON/HC_PROP/WT(50),TB(50),TF(50),TC(50),PC(50),VC(50),ZC(50)
	1	,ACCF(50),WSRK(50),VEST(50),ZRA(50),SOLP(50),VOLP(50)
     2	,QI(50),RI(50),DM(50) 
	DIMENSION SA(7),SB(7),SC(7),SD(7),BB(7),Y(50)	 
      DATA (SA(J),J=1,7)/ 2.4166D0, -5.0924D-1, 6.6107D0, 1.4543D1,
	1						7.9274D-1, -5.8643D0, 9.1089D1 /
      DATA (SB(J),J=1,7)/ 7.4824D-1, -1.5094D0, 5.6207D0, -8.9139D0,
	1						8.2019D-1, 1.2801D1, 1.2811D2 /
      DATA (SC(J),J=1,7)/ -9.1858D-1, -4.9991D1, 6.4760D1, -5.6379D0,
	1						-6.9369D-1, 9.5893D0, -5.4217D1 /
      DATA (SD(J),J=1,7)/ 1.2172D2, 6.9983D1, 2.7039D1, 7.4344D1,
	1						6.3173D0, 6.5529D1, 5.2381D2 /
	DATA RR /8.314D0/
C --- INITIALIZATION 
      IST = 0
	THG = 0.0
	I = ICN

C --- CHECK IF ALL THE AVAILABALE DATA EXISTS 
	IF(TC(ICN).LE.0.) IST = 721
	IF(VC(ICN).LE.0.) IST = 722
	IF(ACCF(ICN).LE.0.) IST = 723
	IF(DM(ICN).LT.0.) IST = 724
	IF(WT(ICN).LE.0.) IST = 725

	IF(IST.NE.0) RETURN
C --- LOW PRESSURE GAS VISCOSITY CALCULATION
	CALL HC_VSGEQN(I,T,VSG,ISTVSG)
	VSG = VSG*1.D-3
	IF(ISTVSG.NE.0) THEN
		CALL HC_VSGCHUNG_LP(I,T,VSG,ISTVSG)
		VSG = VSG*1.D-7
	ENDIF
	IF(ISTVSG.NE.0) THEN
		IST = 726
		RETURN
	ENDIF
C --- HEAT CAPACITY CALCULATION
	CALL HC_CPGEQN(I,T,CPG,ISTCPG)  
	IF (ISTCPG.NE.0) THEN
		IST = 727
		RETURN
	ENDIF
	CV = CPG - RR
C --- THERMAL CONDUCTIVITY CALCUALTION
	TR = T / TC(I)
	VC1 = VC(I)*1.D3
	ZZ = 2.D0+10.5D0*TR*TR
	ALPHA = CV/RR-1.5D0
	BETA = .7862D0-(.7109D0-1.3168D0*ACCF(I))*ACCF(I)
	TERM1 = .215D0+.28288D0*ALPHA-1.061D0*BETA+.26665*ZZ
	TERM2 = .6366D0+BETA*ZZ+1.061D0*ALPHA*BETA
	PSI = 1.D0+ALPHA*TERM1/TERM2
	QQ = 3.586D-3*(TC(I)/(WT(I)*1.D-3))**.5D0/VC1**(2.D0/3.D0)
      DMR=131.3D0*DM(I)/(VC(I)*1.D3*TC(I))**0.5D0
C --- EFFECT OF PRESSURE
	IF ( IEXP .EQ. 0 ) THEN 
		Y(1) = 1.0D0
		IPHASE = 0
		P1 = P*100.D0
		CALL CB_SRK(1,T,P1,RHO,Y,IPHASE,IST)
		IF(IST.NE.0) THEN
			IST = 1728
			RETURN      ! ERROR CODE
		ENDIF
	ENDIF
	YY = VC(I)*1.D3*RHO/6.D0
      CALL CHUNGKP(I,VK)
	DO J=1, 7
		BB(J)=SA(J)+SB(J)*ACCF(I)+SC(J)*DMR**4.D0+SD(J)*VK
	ENDDO
	G1=(1.D0-.5D0*YY)/(1-YY)**3.D0
	G2=BB(1)/YY*(1-DEXP(-BB(4)*YY))+BB(2)*G1*DEXP(BB(5)*YY)+BB(3)*G1
	G2=G2/(BB(1)*BB(4)+BB(2)+BB(3))
	TERM3=1.D0/G2+BB(6)*YY
	TERM4=QQ*BB(7)*YY**2.D0*TR**.5D0*G2
      THG = 31.2D0*VSG*PSI*TERM3/WT(I)/1.D-3+TERM4
      
	RETURN
	END


C*******************************************************************
     END OF FILE